Sub Open()
  dim c as CFDateMBS
  dim t as CFAbsoluteTimeMBS
  
  // get current date
  c=NewCFDateMBS
  
  // in absolute time (seconds since x)
  t=c.AbsoluteTime
  
  // add 600 seconds (= 10 Minutes)
  t.Value=t.Value+600
  
  // Make a Date from it
  c=t.Date
  
  // Schedule the event
  // 0 on success
  // E00002C1 for missing root rights
  Title=hex(schedulePowerEvent(c, "wake"))
  
  // Just for information, display the scheduled stuff
  CFShowMBS CopyScheduledPowerEvents
End Sub

Function CopyScheduledPowerEvents() As cfarrayMBS
  dim s as SoftDeclareMBS
  dim m as MemoryBlock
  
  s=new SoftDeclareMBS
  
  if s.LoadLibrary("IOKit.framework") then
    if s.LoadFunction("IOPMCopyScheduledPowerEvents") then
      if s.CallFunction(0,nil) then
        Return NewCFArrayMBSHandle(s.Result,true)
      else
        MsgBox "Failed to Call IOPMCopyScheduledPowerEvents."
      end if
    else
      MsgBox "Failed to load IOPMCopyScheduledPowerEvents."
    end if
  else
    MsgBox "Failed to load IOKit."
  end if
  
  Return nil
End Function

Function SchedulePowerEvent(time_to_wake as CFDateMBS, Type as CFStringMBS) as Integer
  dim s as SoftDeclareMBS
  dim m as MemoryBlock
  
  '/*
  '* Types of power event
  '* These are potential arguments to IOPMSchedulePowerEvent().
  '* These are all potential values of the kIOPMPowerEventTypeKey in the CFDictionaries
  '* returned by IOPMCopyScheduledPowerEvents().
  '*/
  '/*!
  '@define kIOPMAutoWake
  '@abstract Value for scheduled wake from sleep.
  '*/
  '#define kIOPMAutoWake                                   "wake"
  '
  '/*!
  '@define kIOPMAutoPowerOn
  '@abstract Value for scheduled power on from off state.
  '*/
  '#define kIOPMAutoPowerOn                                "poweron"
  '
  '/*!
  '@define kIOPMAutoWakeOrPowerOn
  '@abstract Value for scheduled wake from sleep, or power on. The system will either wake OR
  'power on, whichever is necessary.
  '*/
  '
  '#define kIOPMAutoWakeOrPowerOn                          "wakepoweron"
  '/*!
  '@define kIOPMAutoSleep
  '@abstract Value for scheduled sleep.
  '*/
  '
  '#define kIOPMAutoSleep                                   "sleep"
  '/*!
  '@define kIOPMAutoShutdown
  '@abstract Value for scheduled shutdown.
  '*/
  '
  '#define kIOPMAutoShutdown                               "shutdown"
  
  s=new SoftDeclareMBS
  
  if s.LoadLibrary("IOKit.framework") then
    if s.LoadFunction("IOPMSchedulePowerEvent") then
      
      m=NewMemoryBlock(12)
      m.Long(0)=time_to_wake.handle
      m.Long(4)=0 // nil
      m.Long(8)=type.Handle
      
      if s.CallFunction(3,m) then
        Return s.Result
      end if
    end if
  end if
  
End Function