Platforms to show: All Mac Windows Linux Cross-Platform
Required plugins for this example: MBS MacCG Plugin, MBS DynaPDF Plugin, MBS MacCF Plugin
Last modified Wed, 14th Sep 2021.
You find this example project in your MBS Xojo Plugin download as a Xojo project file within the examples folder: /DynaPDF/Create and print PDF
Download this example: Create and print PDF.zip
Project "Create and print PDF.xojo_binary_project"
FileTypes
Filetype text
End FileTypes
MenuBar MenuBar1
MenuItem UntitledMenu1 = ""
MenuItem FileMenu = "&File"
MenuItem FileQuit = "Quit"
MenuItem UntitledMenu5 = ""
MenuItem EditMenu = "&Edit"
MenuItem EditUndo = "&Undo"
MenuItem UntitledMenu0 = "-"
MenuItem EditCut = "Cu&t"
MenuItem EditCopy = "&Copy"
MenuItem EditPaste = "&Paste"
MenuItem EditClear = "Clear"
MenuItem UntitledMenu4 = ""
MenuItem UntitledMenu3 = ""
MenuItem UntitledMenu2 = ""
End MenuBar
Class App Inherits Application
End Class
Class Window1 Inherits Window
Control PushButton1 Inherits PushButton
ControlInstance PushButton1 Inherits PushButton
EventHandler Sub Action()
dim pdf as new MyDynapdfMBS
dim d as new date
dim f as FolderItem=SpecialFolder.Desktop.Child("Create and print PDF.pdf")
pdf.SetLicenseKey "Starter" // For this example you can use a Starter, Lite, Pro or Enterprise License
call pdf.CreateNewPDF f
call pdf.SetDocInfo pdf.kdiSubject, "My first Xojo output"
call pdf.SetDocInfo pdf.kdiProducer, "Xojo test application"
call pdf.SetDocInfo pdf.kdiTitle, "My first Xojo output"
// We want to use top-down coordinates
call pdf.SetPageCoords pdf.kpcTopDown
call pdf.Append
call pdf.SetFont "Times", pdf.kfsItalic, 40.0, true, pdf.kcpUnicode
call pdf.WriteFText pdf.ktaCenter, "My first Xojo output!"
call pdf.SetFont "Times", pdf.kfsItalic, 20.0, true, pdf.kcpUnicode
call pdf.WriteText 50.0, 180.0, "File created: " + d.LongDate
call pdf.EndPage
call pdf.CloseFile
End EventHandler
End Control
Control PushButton2 Inherits PushButton
ControlInstance PushButton2 Inherits PushButton
EventHandler Sub Action()
dim f as FolderItem=SpecialFolder.Desktop.Child("Create and print PDF.pdf")
f.Launch
End EventHandler
End Control
Control PushButton3 Inherits PushButton
ControlInstance PushButton3 Inherits PushButton
EventHandler Sub Action()
dim f as FolderItem=SpecialFolder.Desktop.Child("Create and print PDF.pdf")
print f, CheckBox1.Value
End EventHandler
End Control
Control CheckBox1 Inherits CheckBox
ControlInstance CheckBox1 Inherits CheckBox
End Control
Control StaticText1 Inherits Label
ControlInstance StaticText1 Inherits Label
End Control
Sub print(f as FolderItem, ShowDialog as Boolean=true)
if TargetWin32 then
if f=nil or f.Exists=false then
MsgBox "PDF file is missing."
Return
end if
dim r as new RegistryItem("HKEY_CLASSES_ROOT\Software\Adobe\Acrobat\Exe")
dim s as string = r.DefaultValue
if len(s)=0 then
MsgBox "Failed to find Acrobat Reader."
else
shell=new shell
shell.Mode=2
if ShowDialog then
shell.Execute s+" /p """+f.NativePath+""""
else
shell.Execute s+" /h /p """+f.NativePath+""""
end if
end if
else
// Print PDF on Mac
// requires MacOSXCG plugin
dim p as CGPDFDocumentMBS = f.OpenAsCGPDFDocumentMBS
if p=nil then
MsgBox "Failed to read the PDF."
Return
end if
dim g as Graphics
if ShowDialog then
g = OpenPrinterDialog
else
g = OpenPrinter
end if
if g<>Nil then
dim c as integer=p.PageCount
for i as integer=1 to c
g.DrawCGPDFDocumentMBS p, p.CropBox(i), i
if i<c then
g.NextPage
end if
next
end if
end if
Exception rae as RegistryAccessErrorException
MsgBox "Failed to find Acrobat Reader."
End Sub
Property Shell As Shell
End Class
Class MyDynaPDFMBS Inherits DynaPDFMBS
EventHandler Function Error(ErrorCode as integer, ErrorMessage as string, ErrorType as integer) As integer
// output all messages on the console:
System.DebugLog str(ErrorCode)+": "+ErrorMessage
// and display dialog:
Dim d as New MessageDialog //declare the MessageDialog object
Dim b as MessageDialogButton //for handling the result
d.icon=MessageDialog.GraphicCaution //display warning icon
d.ActionButton.Caption="Continue"
d.CancelButton.Visible=True //show the Cancel button
// a warning or an error?
if BitAnd(ErrorType, me.kE_WARNING) = me.kE_WARNING then
// if user decided to ignore, we'll ignore
if IgnoreWarnings then Return 0
d.Message="A warning occurred while processing your PDF code."
// we add a third button to display all warnings
d.AlternateActionButton.Caption = "Ignore warnings"
d.AlternateActionButton.Visible = true
else
d.Message="An error occurred while processing your PDF code."
end if
d.Explanation = str(ErrorCode)+": "+ErrorMessage
b=d.ShowModal //display the dialog
Select Case b //determine which button was pressed.
Case d.ActionButton
Return 0 // ignore
Case d.AlternateActionButton
IgnoreWarnings = true
Return 0 // ignore
Case d.CancelButton
Return -1 // stop
End select
End EventHandler
Property IgnoreWarnings As Boolean
End Class
End Project
See also:
- /DynaPDF/Create Fields with JavaScript Actions
- /DynaPDF/Create PDF and modify XMP
- /DynaPDF/Create PDF in memory
- /DynaPDF/Create PDF with japanese font
- /DynaPDF/Create PDF with over 2 GB size
- /DynaPDF/Create PDF with subscript and superscript
- /DynaPDF/Create PDF with text styles
- /DynaPDF/Create PDF with Trace
- /DynaPDF/Create PDF with WatermarkAnnot
- /DynaPDF/Create PDFX
Download this example: Create and print PDF.zip
The items on this page are in the following plugins: MBS DynaPDF Plugin.
