Platforms to show: All Mac Windows Linux Cross-Platform
/ChartDirector/finance2 animated
Required plugins for this example: MBS ChartDirector Plugin
You find this example project in your Plugins Download as a Xojo project file within the examples folder: /ChartDirector/finance2 animated
This example is the version from Mon, 3rd Feb 2019.
Project "finance2 animated.xojo_binary_project"
Class App Inherits Application
Const kEditClear = "&Löschen"
Const kFileQuit = "Beenden"
Const kFileQuitShortcut = ""
End Class
Class PicWindow Inherits Window
Control Timer1 Inherits Timer
ControlInstance Timer1 Inherits Timer
EventHandler Sub Action()
count=count+1
if count=130 then
me.Mode=me.ModeOff
end if
redraw
End EventHandler
End Control
Control out Inherits Canvas
ControlInstance out Inherits Canvas
EventHandler Sub Paint(g As Graphics, areas() As REALbasic.Rect)
#pragma Unused areas
draw g
End EventHandler
End Control
EventHandler Sub Open()
// Create a finance chart demo containing 100 days of data
const noOfDays = 100
// To compute moving averages starting from the first day, we need to get extra
// data points before the first day
const extraDays = 30
// In this exammple, we use a random number generator utility to simulate the
// data. We set up the random table to create 6 cols x (noOfDays + extraDays)
// rows, using 9 as the seed.
rantable = new CDRanTableMBS(9, 6, noOfDays + extraDays)
// Set the 1st col to be the timeStamp, starting from Sep 4, 2002, with each row
// representing one day, and counting week days only (jump over Sat and Sun)
rantable.setDateCol(0, CDFinanceChartMBS.chartTime(2002, 9, 4), 86400, true)
// Set the 2nd, 3rd, 4th and 5th columns to be high, low, open and close data.
// The open value starts from 100, and the daily change is random from -5 to 5.
rantable.setHLOCCols(1, 100, -5, 5)
// Set the 6th column as the vol data from 5 to 25 million
rantable.setCol(5, 50000000, 250000000)
count=30
End EventHandler
Sub draw(g as Graphics)
// To compute moving averages starting from the first day, we need to get extra
// data points before the first day
const extraDays = 30
// Now we read the data from the table into arrays
dim timeStamps(-1) as double = rantable.getCol(0).Values
dim highData(-1) as double = rantable.getCol(1).Values
dim lowData(-1) as double = rantable.getCol(2).Values
dim openData(-1) as double = rantable.getCol(3).Values
dim closeData(-1) as double = rantable.getCol(4).Values
dim volData(-1) as double = rantable.getCol(5).Values
// Create a FinanceChart object of width 640 pixels
dim c as new CDFinanceChartMBS(640)
for i as integer=count to UBound(timeStamps)
highData(i)=c.kNoValue
lowData(i)=c.kNoValue
openData(i)=c.kNoValue
closeData(i)=c.kNoValue
volData(i)=c.kNoValue
next
// Add a title to the chart
call c.addTitle("Finance Chart Demonstration")
// Set the data into the finance chart object
call c.setData(timeStamps, highData, lowData, openData, closeData, volData, extraDays)
// Add a slow stochastic chart (75 pixels high) with %K = 14 and %D = 3
dim s as CDXYChartMBS = c.addSlowStochastic(75, 14, 3, &h006060, &h606000)
s.yAxis.setLinearScale 0,100
// Add the main chart with 240 pixels in height
dim main as CDXYChartMBS = c.addMainChart(240)
main.yAxis.setLinearScale 70,160
// Add a 10 period simple moving average to the main chart, using brown color
call c.addSimpleMovingAvg(10, &h663300)
// Add a 20 period simple moving average to the main chart, using purple color
call c.addSimpleMovingAvg(20, &h9900ff)
// Add an HLOC symbols to the main chart, using green/red for up/down days
call c.addCandleStick(&h00ff00, &hff0000)
// Add 20 days donchian channel to the main chart, using light blue (9999ff) as
// the border and semi-transparent blue (c06666ff) as the fill color
call c.addDonchianChannel(20, &h9999ff, &hc06666ff)
// Add a 75 pixels volume bars sub-chart to the bottom of the main chart, using
// green/red/grey for up/down/flat days
call c.addVolBars(75, &h99ff99, &hff9999, &h808080)
// Append a MACD(26, 12) indicator chart (75 pixels high) after the main chart,
// using 9 days for computing divergence.
dim m as CDXYChartMBS = c.addMACD(75, 26, 12, 9, &h0000ff, &hff00ff, &h008000)
m.yAxis.setLinearScale -10,20
// Output the chart
g.DrawPicture c.makeChartPicture,0,0
End Sub
Sub redraw()
out.Invalidate
End Sub
Property count As Integer
Property rantable As CDRanTableMBS
End Class
MenuBar MenuBar1
MenuItem FileMenu = "&Ablage"
MenuItem FileQuit = "#App.kFileQuit"
MenuItem EditMenu = "&Bearbeiten"
MenuItem EditUndo = "&Rückgängig"
MenuItem UntitledMenu1 = "-"
MenuItem EditCut = "&Ausschneiden"
MenuItem EditCopy = "&Kopieren"
MenuItem EditPaste = "&Einfügen"
MenuItem EditClear = "#App.kEditClear"
MenuItem UntitledMenu0 = "-"
MenuItem EditSelectAll = "&Alles auswählen"
End MenuBar
End Project
See also:
The items on this page are in the following plugins: MBS ChartDirector Plugin.