// create with values and read them back
dim a as AXValueMBS = AccessibilityMBS.MakeAXValueFromCFRange(5, 9)

if a.AXIsCFRange then
  dim lo, le as Integer
  
  if a.AXGetCFRange(lo, le) then
    MsgBox str(lo)+" "+str(le)
  else
    break // error
  end if
else
  break // error
end if

// displays the current window title if accessibility is enabled in Mac OS X 10.2 or newer
// your application needs permissions for accessibility to make this work!

dim SystemWideElement,FocusedApplicationElement,FocusedWindowElement as AXUIElementMBS
dim FocusedApplication,FocusedWindow,Title as AXValueMBS
dim s as String
dim cs as CFStringMBS

// show a window so there is one which can be found
window1.show

SystemWideElement=AccessibilityMBS.SystemWideAXUIElement
if SystemWideElement<>nil then
  FocusedApplication=SystemWideElement.AttributeValue(AccessibilityMBS.kAXFocusedApplicationAttribute)
  if FocusedApplication.Type=AccessibilityMBS.kAXUIElementMBSTypeID then
    FocusedApplicationElement=new AXUIElementMBS
    FocusedApplicationElement.Handle=FocusedApplication.Handle
    FocusedApplicationElement.RetainObject
    
    FocusedWindow=FocusedApplicationElement.AttributeValue(AccessibilityMBS.kAXFocusedWindowAttribute)
    
    if FocusedWindow<>nil and AccessibilityMBS.kAXUIElementMBSTypeID=FocusedWindow.Type then
      
      FocusedWindowElement=new AXUIElementMBS
      FocusedWindowElement.Handle=FocusedWindow.Handle
      FocusedWindowElement.RetainObject
      
      Title=FocusedWindowElement.AttributeValue(AccessibilityMBS.kAXTitleAttribute)
      if Title<>nil and Title.Type=kCFStringMBSTypeID then
        cs=new CFStringMBS
        cs.handle=Title.Handle
        cs.RetainObject
        msgbox cs.str
      end if
    end if
  end if
end if