PDFDocumentMBS.appendPage(page as PDFPageMBS)

PDFDocumentMBS.beginFindString(text as string, options as Integer)

Search results are handled via a DidFindMatch event in the delegate. Supported options are: NSCaseInsensitiveSearch, NSLiteralSearch, and NSBackwardsSearch.

PDFDocumentMBS.beginFindStrings(texts() as string, options as integer)

PDFDocumentMBS.cancelFindString

Can be called from a user method being serviced by a find notification.

PDFDocumentMBS.Constructor

dim doc as new PDFDocumentMBS // new empty document
dim page as new PDFPageMBS // new empty page

doc.Creator="Xojo"
doc.Title="Test file"

doc.insertPage page,0

dim f as FolderItem=SpecialFolder.Desktop.Child("test.pdf")

if doc.write(f) then
  f.launch
end if

See also:

• Constructor(data as memoryblock)
• Constructor(data as String)
• Constructor(file as folderitem)
• Constructor(Handle as Integer)

PDFDocumentMBS.Constructor(data as memoryblock)

dim f as FolderItem = SpecialFolder.Desktop.Child("test.pdf")
dim b as BinaryStream = f.OpenAsBinaryFile(false)
dim s as string = b.Read(b.Length)

dim doc as new PDFDocumentMBS(s)

MsgBox doc.Title

See also:

• Constructor
• Constructor(data as String)
• Constructor(file as folderitem)
• Constructor(Handle as Integer)

PDFDocumentMBS.Constructor(data as String)

See also:

• Constructor
• Constructor(data as memoryblock)
• Constructor(file as folderitem)
• Constructor(Handle as Integer)

PDFDocumentMBS.Constructor(file as folderitem)

dim p as PDFDocumentMBS
dim f as FolderItem

f=SpecialFolder.Desktop.Child("test.pdf")
p=new PDFDocumentMBS(f)

MsgBox "Text from first page:"+EndOfLine+EndOfLine+p.pageAtIndex(0).stringValue

See also:

• Constructor
• Constructor(data as memoryblock)
• Constructor(data as String)
• Constructor(Handle as Integer)

PDFDocumentMBS.Constructor(Handle as Integer)

Please pass in a non zero handle which points to a PDFDocument object.
For use with declares.

See also:

• Constructor
• Constructor(data as memoryblock)
• Constructor(data as String)
• Constructor(file as folderitem)

PDFDocumentMBS.copy as PDFDocumentMBS

dim f as FolderItem = SpecialFolder.Desktop.Child("test.pdf")
dim p as new PDFDocumentMBS(f)

// make a copy
dim c as PDFDocumentMBS = p.copy

// remove second page
c.removePageAtIndex 1

// c has one page less
MsgBox str(p.pageCount)+" "+str(c.pageCount)

For Mac OS X 10.7 and newer this function uses the framework function.
For Mac OS X 10.6 and older this function uses our own copy function to duplicate the document.

PDFDocumentMBS.dataRepresentation(QuartzFilter as Variant = nil) as memoryblock

dim f as FolderItem = SpecialFolder.Desktop.Child("test.pdf")
dim doc as new PDFDocumentMBS(f)

dim o as FolderItem = SpecialFolder.Desktop.Child("out.pdf")
dim b as BinaryStream = o.CreateBinaryFile("")

b.Write doc.dataRepresentation

Optional for Mac OS X 10.6, you can pass a QuartzFilterMBS object to use that filter here.

Looks like newer macOS versions like 10.14 or later ignore the quartz filter.

PDFDocumentMBS.documentAttributes as Dictionary

Returns a dictionary with PDF metadata. Metadata is optional for PDF's and so some of the keys may be missing or the entire dictionary may be empty.
(Read and Write computed property)

PDFDocumentMBS.exchangePageAtIndexWithPageAtIndex(indexA as Integer, indexB as Integer)

Index is zero based.

PDFDocumentMBS.findString(text as string, options as Integer) as PDFSelectionMBS()

dim p as PDFDocumentMBS
dim f as FolderItem
dim sa() as PDFSelectionMBS
dim i,c as Integer
dim s as PDFSelectionMBS

const NSCaseInsensitiveSearch=1

f=SpecialFolder.Desktop.Child("test.pdf")
p=new PDFDocumentMBS(f)

if p.pageCount=0 then
  MsgBox "Failed to load the PDF."
  Return
end if

sa=p.findString("Plugin",NSCaseInsensitiveSearch)

if ubound(sa)<0 then
  MsgBox "no item found."
else
  MsgBox str(ubound(sa)+1)+" items found."
end if

s=sa(0)
s.extendSelectionAtEnd(50)
s.extendSelectionAtStart(50)

MsgBox s.stringValue // shows a bit more text before and after the location found

May return an empty array if nothing is found.
Returns nil on any error.

Supported options are:
NSCaseInsensitiveSearch, NSLiteralSearch, and NSBackwardsSearch.

PDFDocumentMBS.findStringFromSelection(text as string, selection as PDFSelectionMBS, options as Integer) as PDFSelectionMBS

Returns next instance as a PDFSelection or nil if the end of the document is reached. Supported options are: NSCaseInsensitiveSearch, NSLiteralSearch, and NSBackwardsSearch. Passing in nil for selection will start the search from the beginning of the document (or end if NSBackwardsSearch is specified).

PDFDocumentMBS.indexForPage(page as PDFPageMBS) as Integer

Indicees are zero-based.

PDFDocumentMBS.insertPage(page as PDFPageMBS, index as Integer)

dim file1,file2,file3,destfile as FolderItem
dim page1,page2,page3 as PDFPageMBS
dim doc1,doc2 as PDFDocumentMBS
dim img as NSImageMBS
dim doc as PDFDocumentMBS

file1=SpecialFolder.Desktop.Child("test1.pdf")
file2=SpecialFolder.Desktop.Child("test2.pdf")
file3=SpecialFolder.Desktop.Child("logo.jpg")

doc1=new PDFDocumentMBS(file1)
doc2=new PDFDocumentMBS(file2)

MsgBox str(doc1.pageCount)

img=new NSImageMBS(file3)

Backdrop=img.CopyPicture

page1=new PDFPageMBS(img)
page2=doc1.pageAtIndex(0)
page3=doc2.pageAtIndex(0)

doc=new PDFDocumentMBS
doc.insertPage page1,0
doc.insertPage page2,1
doc.insertPage page3,2

destfile=SpecialFolder.Desktop.Child("test.pdf")
call doc.write(destfile)

Index is zero based.

Some examples using this method:

• /MacCocoa/Apply Quartz Filters to PDF
• /PDFKit/Create Page
• /PDFKit/Create Page with custom stamp annotation
• /PDFKit/Create Page with Page
• /PDFKit/PDFView/PDFView overlay/PDFView overlay
• /PDFKit/PDFView/PDFView overlay/PDFViewControl overlay

PDFDocumentMBS.Keywords as string()

dim f as FolderItem = SpecialFolder.Desktop.Child("test.pdf")
dim doc as new PDFDocumentMBS(f)
MsgBox join(doc.Keywords)

PDFDocumentMBS.outlineItemForSelection(selection as PDFSelectionMBS) as PDFOutlineMBS

Since a selection may span multiple outline items, only the point representing the first character of the PDFSelection is considered. Typically, outline's indicate things like chapters for the PDF. Therefore, this method would help you identify the chapter the selection falls within.

For some PDFs this method returns nil.

PDFDocumentMBS.pageAtIndex(index as Integer) as PDFPageMBS

dim p as PDFDocumentMBS
dim f as FolderItem

f=SpecialFolder.Desktop.Child("test.pdf")
p=new PDFDocumentMBS(f)

MsgBox "Text from first page:"+EndOfLine+EndOfLine+p.pageAtIndex(0).stringValue

Will raise an exception if index is out of bounds. Indicees are zero-based.

Some examples using this method:

• /MacExtras/Continuity Camera
• /MacFrameworks/IKSlideShow
• /PDFKit/Add Annotations to PDF
• /PDFKit/Add Outlines with Actions to PDF
• /PDFKit/Add Outlines with Destinations to PDF
• /PDFKit/Create Page with Page
• /PDFKit/PDFKit Print PDF
• /PDFKit/PDFView/PDFView overlay/PDFViewControl overlay
• /PDFKit/Render PDFPage
• /WinFrameworks/Windows PDF Viewer

PDFDocumentMBS.PrintOperation(PrintInfo as Variant, AutoRotate as boolean = true, scalingMode as Integer = 0) as Variant

// select a PDF
dim f as FolderItem = GetOpenFolderItem("")
if f = nil then Return

// open PDF
dim doc as new PDFDocumentMBS(f)

// define some print setting via PrintInfo
dim PrintInfo as new NSPrintInfoMBS

// start print operation
dim printOperation as NSPrintOperationMBS = doc.PrintOperation(printinfo)

printOperation.showsPrintPanel = true
printOperation.showsProgressPanel = true

call printOperation.runOperation

Returns NSPrintOperationMBS object.

PDFDocumentMBS.removePageAtIndex(index as Integer)

Index is zero based.

Some examples using this method:

• /PDFKit/PDFView/PDFView overlay/PDFView overlay
• /PDFKit/PDFView/PDFView overlay/PDFViewControl overlay

PDFDocumentMBS.selectionForEntireDocument as PDFSelectionMBS

PDFDocumentMBS.selectionFromPage(StartPage as PDFPageMBS, StartCharacterIndex as Integer, EndPage as PDFPageMBS, EndCharacterIndex as Integer) as PDFSelectionMBS

Start and end page can be the same.

See also:

• selectionFromPage(StartPage as PDFPageMBS, StartPointX as single, StartPointY as single, EndPage as PDFPageMBS, EndPointX as single, EndPointY as single) as PDFSelectionMBS

PDFDocumentMBS.selectionFromPage(StartPage as PDFPageMBS, StartPointX as single, StartPointY as single, EndPage as PDFPageMBS, EndPointX as single, EndPointY as single) as PDFSelectionMBS

Points are in page-space and relative to their respective pages. Start and end page can be the same (and are then equivalent to calling selectionFromPointToPoint).

See also:

• selectionFromPage(StartPage as PDFPageMBS, StartCharacterIndex as Integer, EndPage as PDFPageMBS, EndCharacterIndex as Integer) as PDFSelectionMBS

PDFDocumentMBS.SetDelegate(d as PDFDocumentDelegateMBS)

PDFDocumentMBS.SetKeywords(keywords() as string)

PDFDocumentMBS.unlockWithPassword(password as string) as boolean

dim f as FolderItem = SpecialFolder.Desktop.Child("test.pdf")
dim doc as new PDFDocumentMBS(f)

if doc.unlockWithPassword("mypassword") then
  MsgBox "OK"
end if

Means of passing in a password to unlock encrypted PDF's. Calling unlockWithPassword will attempt to unlock the PDF. If successful, a DidUnlockDocument event is sent to the delegate. You cannot "re-lock" a PDF by passing in a bogus password. Returns true if the document is now unlocked, false otherwise (isLocked = false).

PDFDocumentMBS.write(file as folderitem, QuartzFilter as Variant = nil) as boolean

dim f as FolderItem = SpecialFolder.Desktop.Child("test.pdf")
dim doc as new PDFDocumentMBS(f)

// modify here

dim o as FolderItem = SpecialFolder.Desktop.Child("testout.pdf")
call doc.write(o)

Returns true on success and false on failure.

There is a bug known in Mac OS X 10.4 that this function may return true even if the saving failed. So you may prefer to check the file whether it exists after write.

Optional for Mac OS X 10.6, you can pass a QuartzFilterMBS object to use that filter here.

Looks like newer macOS versions like 10.14 or later ignore the quartz filter.

PDFDocumentMBS.writeWithOptions(file as folderitem, options as dictionary) as boolean

Returns true on success and false on failure.

Some keys to use include:
CGPDFContextMBS.kCGPDFContextUserPassword
CGPDFContextMBS.kCGPDFContextTitle
CGPDFContextMBS.kCGPDFContextSubject
CGPDFContextMBS.kCGPDFContextOwnerPassword
CGPDFContextMBS.kCGPDFContextOutputIntents
CGPDFContextMBS.kCGPDFContextOutputIntent
CGPDFContextMBS.kCGPDFContextKeywords
CGPDFContextMBS.kCGPDFContextEncryptionKeyLength
CGPDFContextMBS.kCGPDFContextCreator
CGPDFContextMBS.kCGPDFContextAuthor
CGPDFContextMBS.kCGPDFContextAllowsPrinting
CGPDFContextMBS.kCGPDFContextAllowsCopying