// Reads file names from persistent dock applications and puts them into the list

dim pref as new CFPreferencesMBS

dim persistentapps as CFStringMBS = NewCFStringMBS("persistent-apps")
dim ApplicationID  as CFStringMBS = NewCFStringMBS("com.apple.dock")
dim tiledata       as CFStringMBS = NewCFStringMBS("tile-data")
dim filelabel      as CFStringMBS = NewCFStringMBS("file-label")

// get the array of persistent applications from dock preferences
dim o as CFObjectMBS = pref.CopyValue(persistentapps, ApplicationID, pref.kCFPreferencesCurrentUser, pref.kCFPreferencesAnyHost)

if o isa CFArrayMBS then
  dim a as CFArrayMBS = CFArrayMBS(o)
  
  // walk over all items in array
  dim c as Integer = a.Count-1
  for i as Integer = 0 to c
    
    // get dictionary describing item
    o = a.Item(i)
    
    if o isa CFDictionaryMBS then
      dim d as CFDictionaryMBS = CFDictionaryMBS(o)
      
      // and pick tile data dictionary
      o = d.Value(tiledata)
      if o isa CFDictionaryMBS then
        d = CFDictionaryMBS(o)
        
        // and pick there the file label
        o = d.Value(filelabel)
        if o isa CFStringMBS then
          // and display it
          dim name as string = CFStringMBS(o).str
          List.AddRow name
        end if
      end if
    end if
    
  next
  
else
  MsgBox "Failed to read dock preferences."
end if